***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 07, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   2N7002KTB     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     204.06
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=0.5  VTO=2.0  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=2.5e10  gamma=1.7)
Rd     d1    d2    1.39 TC=7m,23u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=66  TBV1=7.955e-4   CJO=2.740e-12  M=2.924e-1  VJ=0.3905)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=2.646e-13  N=1.000  RS=12.04u  EG=1.00  TT=20n ikf=1.083e-3)
Rdiode  d1  21    2.056e-1 TC=-3.5m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   7.175e-12
.MODEL     DGD    D(M=3.479e-1   CJO=7.175e-12   VJ=0.3905)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    6.79266e-12
.ENDS
*$
